Wikipédia:Magyar települések műhelye/Wikidata

Ezen az oldalon olyan lekérdezéseket gyűjtünk, amelyeket a Wikidatán lefuttatva a magyarországi településekre vonatkozó hibákat, hiányosságokat megmutatja.

Magyarországi városok és kategóriáik

A lekérdezés kilistázza Magyarország városait, és azokat a kategóriákat, amelyek a településekhez kapcsolódnak (pl.: fő kategória, itt született személyek, filmes helyszínek, díszpolgárok stb.). A lekérdezés arra jó, hogy szükség esetén új kategóriákat létrehozzunk, vagy a már meglévő, de a Wikidata adatlaphoz nem kapcsolt kategóriákat összekapcsoljuk a fő szócikk elemével.

SELECT ?item ?itemLabel ?fo ?foLabel ?hc ?hcLabel ?kapcs ?kapcsLabel ?szulet ?szuletLabel ?elhunyt ?elhunytLabel ?nyug ?nyugLabel ?filmek ?filmekLabel ?map ?mapLabel WHERE {
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],hu". }
  ?item wdt:P31 wd:Q13218690.
  OPTIONAL { ?item wdt:P11620 ?mnnf. }
  OPTIONAL { ?item wdt:P910 ?fo. }
  OPTIONAL { ?item wdt:P1792 ?kapcs. }
  OPTIONAL { ?item wdt:P1464 ?szulet. }
  OPTIONAL { ?item wdt:P1465 ?elhunyt. }
  OPTIONAL { ?item wdt:P1791 ?nyug. }
  OPTIONAL { ?item wdt:P1740 ?filmek. }
  OPTIONAL { ?item wdt:P7867 ?map. }
  OPTIONAL { ?item wdt:P10280 ?hc. }
}

Próbáld ki!

Honlap nélküli települési szócikkek

A lekérdezés kilistázza azokat a ma is létező településeket, amelyekhez nincs megadva hivatalos weboldal (P856), továbbá megmutatja, hogy a legfrissebb adatok szerint a települést hányan lakják. Megjegyzés: az ezer főnél nagyobb településeknek a tapasztalatok szerint van honlapjuk. Ahol ennél kevesebben laknak, változó, hogy van-e honlap vagy nincs.

SELECT ?item ?itemLabel ?honl WHERE {
  SERVICE wikibase:label { bd:serviceParam wikibase:language "en". }
  { ?item wdt:P31 wd:Q2590631. } UNION { ?item wdt:P31 wd:Q13218690. }
  MINUS { ?item wdt:P856 _:b2. }
  FILTER NOT EXISTS{ ?item wdt:P576 _:b8 }   
    OPTIONAL { ?item wdt:P1082 ?honl. }
}

2023. november 28-án 351 település volt a listán.

ORDER BY ?itemLabel

Próbáld ki!

Települések címer nélkül

Azok a települések, melyeknél a Wikidata adatlapon nem szerepel címer (P94) tulajdonság. A listában megjelenik a Magyar Nemzeti Névtér azonosító, és (ha van) a település honlapjának a linkje, így könnyű ellenőrizni, hogy egyáltalán van-e címere a településnek, vagy azért hiányzik az adatlapról, mert nincs is neki.

SELECT ?item ?itemLabel ?mnnf ?web WHERE {
  SERVICE wikibase:label { bd:serviceParam wikibase:language "hu". }
  { ?item wdt:P31 wd:Q2590631. } UNION { ?item wdt:P31 wd:Q13218690. }
  MINUS { ?item wdt:P94 _:b2. }
  FILTER NOT EXISTS{ ?item wdt:P576 _:b8 }  
  OPTIONAL { ?item wdt:P11620 ?mnnf. }
  OPTIONAL { ?item wdt:P856 ?web. }
}

Próbáld ki!

2023. november 28-án 324 település volt a listán.

Települések képei, képaláírással és egyéb adatokkal

Azok a települési adatlapok, ahol szerepel kép (P18). Ahol van képaláírás magyar nyelven, ott az is látszik, valamint a kép készítésének időpontja (ez utóbbi a Commonsból átmásolva). Megmutatja, hogy melyik Wikimédia projektből importálták az adatokat. Ha valamelyik adat nem szerepel, ott üres marad a rubrika. Ha valamelyik település elemében több kép is fel van töltve, akkor azokat külön-külön mutatja meg, így a rekordok száma több lehet, mint a képpel rendelkező települések száma.

SELECT ?item ?itemLabel ?date ?régi_mnnf ?mnnf ?pict ?kepala ?refLabel WHERE {
  SERVICE wikibase:label { bd:serviceParam wikibase:language "hu". }
  { ?item wdt:P31 wd:Q2590631. } UNION { ?item wdt:P31 wd:Q13218690. }
  ?item wdt:P18 [].
  ?item p:P18 ?statement.
  ?statement ps:P18 ?pict.
  OPTIONAL { ?item wdt:P6987 ?régi_mnnf. }
  OPTIONAL { ?item wdt:P11620 ?mnnf. }  
  OPTIONAL { ?statement pq:P585 ?date. }
  OPTIONAL { ?statement pq:P2096 ?kepala. filter(lang(?kepala)="hu")}
  OPTIONAL { ?statement (prov:wasDerivedFrom/pr:P143) ?ref. }
}

ORDER BY DESC (?date)

Próbáld ki!